As other devonthink users, I would love to use punakea for tagging files inside a DT database. Although I can drag and drop a file from DT into Punakea, even tag it, it does not show up in the punakea browser (although the new tag does).
I hope the tagging of items in a Devonthink database will be possible one day! For everything else, especially in the finder, this is already a nice app.
DevonThink & punakea: drag and drop tagging ?
Submitted by Maak on April 22, 2008 - 20:13.
|
I believe that DTP 2.0 will
I believe that DTP 2.0 will have a different database structure permitting this. When you import a file that is actually copied as a file into DTP (i.e. importing a PDF actually creates a copy of the file within the database package, while importing an rtf seems to just add the information to a .database file), spotlight comments are more or less separated from that file. Comments subsequently added through DTP remain separated until export. I let Punakea handle the storage of my files and then have DTP index my tag folder. If you index the folder structure that Punakea generates for your tags, DB can get pretty messy with a bunch of duplicate entries all over the place, so you might want to consider creating a special DTP tag and only index that folder in your tag folder (that is, if you are only interested in a subset of a large collection of files).
I have written an applescript to add tags to files in DTP that are formatted for Punakea, though they will only be recognized until you export them. It is not as useful as the actual Punakea tagger, but it may be useful if you use DTP as an inbox for grabbing files to be sorted later.
-- Script to present a comment allowing the addition of comments to record(s)
-- v 1.7
-- Grabbing preference values
property tag_prepend : "###begin_tags###"
property tag_append : "###end_tags###"
property tag_prefix : "@"
property tag_separator : ";"
property tag_spacer : " "
tell application "DEVONthink Pro"
activate
try
set this_selection to the selection
if this_selection is {} then error "Please select some contents."
set theResult to display dialog ¬
"Tags" default answer ¬
"Add additional tags (separate with commas)" buttons {"Cancel", "OK"} ¬
default button 2 with title "Add Tags"
set file_tags to text returned of theResult
set tag_string to my formatTags(file_tags) -- Processing the file tags to encode in the correct format
repeat with this_record in this_selection
set current_comment to comment of this_record
--Record already has some comments; prepare to format for Punakea
if current_comment is not "" then
--There are already Punakea formatted tags
if current_comment contains tag_prefix then set current_comment to my extractTags(current_comment)
set combo_string to file_tags & ", " & current_comment
set combo_string to my formatTags(combo_string) -- Processing the file tags to encode in the correct format
set the comment of this_record to combo_string
else
set the comment of this_record to tag_string
end if
end repeat
on error error_message number error_number
if the error_number is not -128 then
try
display alert "DEVONthink Pro" message error_message as warning
on error number error_number
if error_number is -1708 then display dialog error_message buttons {"OK"} default button 1
end try
end if
end try
end tell
on formatTags(file_tags)
if (file_tags is not "") and (file_tags is not "Enter file tags (separate with commas)") then
set current_delimiter to AppleScript's text item delimiters
set AppleScript's text item delimiters to ", "
set tag_string to tag_spacer & tag_prepend -- Adding the string prefix for Punakea
repeat with i from 1 to the count of text items of the file_tags
set this_tag to text item i of the file_tags
set tag_string to tag_string & (tag_prefix & this_tag & tag_separator)
end repeat
set tag_string to tag_string & tag_append -- Adding the string suffix for Punakea
set AppleScript's text item delimiters to ""
set AppleScript's text item delimiters to current_delimiter
return tag_string
else
return ""
end if
end formatTags
on extractTags(currentTag) --v 1.9
if currentTag contains tag_prepend then -- File has Punakea tags
set AppleScript's text item delimiters to ""
set AppleScript's text item delimiters to tag_prepend
set currentString to text item 2 in currentTag
set preTag to text item 1 in currentTag -- anything that comes before the tag string
set AppleScript's text item delimiters to tag_append
set postTag to text item 2 in currentString -- anything that comes after the tag string
set currentString to text item 1 in currentString
set AppleScript's text item delimiters to tag_prefix
set currentString to every text item of currentString
set AppleScript's text item delimiters to ""
set currentString to currentString as Unicode text
set currentString to preTag & currentString & postTag
set AppleScript's text item delimiters to the tag_separator
set the item_list to every text item of currentString
set AppleScript's text item delimiters to ", "
set this_text to the item_list as string
set AppleScript's text item delimiters to ""
end if
return this_text
end extractTags
Thanks for helping, VB-23 :)
Thanks for helping, VB-23 :)